German noun declensions

 

  The overall structure of our (nonmonotonic) declension hierarchy is shown above. It has the Noun node at the top and this is characterized by the -s suffix frequently found in genitive singulars and in the plurals of a small set of common German nouns. This latter may seem a curious choice for the default plural suffix for German since it occurs much less frequently than the other plural suffixes, However, we are persuaded by the extensive linguistic evidence given by Clahsen and his collaborators that -s is the default plural suffix for German (see Clahsen et al. (1992, 228-229), Clahsen et al. (1996, 119-122), Marcus et al. (1995, 229-231). See also Carstairs-McCarthy (1992, 232), Kilbury (1995) and Wiese (1996a, 138)). It is not a view that Wurzel is willing to adopt - he remarks that ``it is incompatible with the facts of German inflectional morphology!'' (1990, 215 n6). And yet it is the suffix that standardly occurs with surnames, product names, acronyms, truncated nouns, unassimilated borrowings, foreign words, derived forms, neologisms, onamatopoeic nouns, and nouns formed from VPs and APs. That is sufficient evidence to persuade us that it is indeed the default plural.

The full definition for the Noun node is shown below. We specify gender in our analysis only because certain suffixes are sensitive to the gender of the root. For technical convenience we make masculine the default gender and stipulate feminine and neuter on individual lexemes as appropriate. However, gender in German (and Dutch) is largely predictable on the basis of phonology, semantics and declension and, in forthcoming work, we provide a comprehensive predictive account of German gender. That account can simply replace the stipulations made here (cf. Fraser & Corbett (1995, 128-130) for a predictive account of Russian gender).

Noun:
    <> == Word
    <syn gender> == masc
    <mor suffix> == "Suffix_s:<phn root form>"
    <phn $yll peak> == IF:<AND:<"<mor umlaut>"
                                EQ:<plur>
                                EQ:<$yll "<phn root focus>">>
                       THEN Umlaut:<"<phn $yll peak->">
                       ELSE         "<phn $yll peak->">.

The subclasses of nouns which follow the Noun pattern (class VIII$^{\prime\prime}$ for Carstairs 1987, 241) in their singulars but inflect their plural forms differently are defined as follows. Noun_A nouns (strong for Carstairs 1987, 241) have an -e suffix in the plural, (e.g. Arm, Arm-e); Noun_B nouns (also strong for Carstairs 1987, 241) are a subclass of Noun_A nouns, with the same suffix, but additionally an umlauted root (e.g. Fuss, Füss-e); Noun_C nouns (class VII for Carstairs 1987, 241) have an umlaut and an -er suffix (e.g. Mann, Männ-er); Noun_D nouns (class XIV$^{\prime\prime}$ for Carstairs 1987, 241) have an -en suffix (e.g. Frau, Frau-en). This analysis of the main noun classes is fully PEP-compliant, where a morphological analysis is PEP-compliant if and only if it is consistent with the Paradigm Economy Principle. As Carstairs notes, German nouns provide a severe challenge to that principle (1987, 234). The only substantive distinctions between his taxonomy and ours arise from our treatment of umlaut: Carstairs does not consider stem alternation to be a factor in determining paradigms.

Noun_A:
    <> == Noun
    <mor suffix plur> == "Suffix_e2:<phn root form plur>".

Noun_B:
    <> == Noun_A
    <mor umlaut> == T.

Noun_C:
    <> == Noun
    <mor umlaut> == T
    <mor suffix plur> == "Suffix_er:<phn root form plur>".

Noun_D:
    <> == Noun
    <mor suffix plur> == "Suffix_en1:<phn root form plur>".

The Noun_D declension itself has a variety of subclasses which inflect in different ways in their singular forms. They can be defined as follows. Noun_E nouns have an -um suffix in the singular (e.g. Alb-um, Alb-en); Noun_F nouns have an -a suffix in the singular (e.g. Dogm-a, Dogm-en); Noun_G nouns have an -is suffix in the singular (e.g. Thes-is, Thes-en); Noun_H nouns have an -us suffix in the singular (e.g. Bazill-us, Bazill-en).

Noun_E:
    <> == Noun_D
    <mor suffix sing> == "Suffix_um:<phn root form sing>".

Noun_F:
    <> == Noun_D
    <mor suffix sing> == "Suffix_a:<phn root form sing>".

Noun_G:
    <> == Noun_D
    <mor suffix sing> == "Suffix_is:<phn root form sing>".

Noun_H:
    <> == Noun_D
    <mor suffix sing> == "Suffix_us:<phn root form sing>".

Two further declensions can be defined by reference to one of those just given: Noun_I nouns have the same -us suffix in the singulars as Noun_H nouns but use -i to mark their plural forms (e.g. Mod-us, Mod-i). Noun_M nouns have the same plural suffix as Noun_I, but use -o to mark the singular (e.g. Cell-o, Cell-i).

Noun_I:
    <> == Noun_H
    <mor suffix plur> == "Suffix_i:<phn root form plur>".

Noun_M:
    <> == Noun_I
    <mor suffix sing> == "Suffix_o:<phn root form sing>".

It should be noted that these further classes maintain PEP-compliance since each introduces an additional suffix. Carstairs himself does not provide for most of these classes, presumably because they mostly comprise foreign words. The two foreign words which he does include, Museum and Cello, he treats as undergoing truncation plus suffixation in their plurals. Although Carstairs treats these as individual exceptions, CELEX lists 182 nouns which behave like Museum and 5 which behave like Cello. We make a distinction between the root and citation forms and provide singular suffixes. This then leads to our additional classes.

The so-called weak nouns come in two main varieties: Noun_J nouns have an -en suffix for all singular and plural forms (e.g. Has-en) except the nominative singular which takes -e (e.g. Has-e). Noun_K nouns are just like Noun_J nouns except in the singular genitive where -ens appears. This is the one area of our account which is not fully PEP-compliant. However, as can be seen from the lengthy discussion Carstairs (1987, 241-50) himself devotes to these nouns, they are genuinely problematic for the Paradigm Economy Principle. In his view, they are undergoing a shift which will restore compliance.

Noun_J:
    <> == Noun_D
    <mor suffix sing> == "Suffix_en1:<phn root form sing>"
    <mor suffix sing nom> == "Suffix_e2:<phn root form sing nom>".

Noun_K:
    <> == Noun_J
    <mor suffix sing gen> == "Suffix_en2:<phn root form sing gen>".

Finally, the Noun_L declension, which is yet another subdeclension of Noun_D, has, as already noted, different focussed syllables in its singular and plural roots and, in addition, exhibits vowel lengthening in the final syllable of plurals.

Noun_L:
    <> == Noun_D
    <phn root focus sing> == syl2
    <phn syl1 peak plur> == Lengthen:<"<phn syl1 peak- plur>">.